Dynamics 365 Business Central: การใช้งาน Dictionary Data Type ใน AL Programming

procedure AddToDictionary(var Dict: Dictionary of [Integer, Text]; Id: Integer; Value: Text)
begin
    if not Dict.ContainsKey(Id) then begin
        Dict.Add(Id, Value);
        Message('Added Key %1 with Value %2', Id, Value);
    end else
        Error('Key %1 already exists.', Id);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    AddToDictionary(MyDictionary, 1, 'Apple');
    AddToDictionary(MyDictionary, 2, 'Banana');
end;

procedure CheckKeyExists(var Dict: Dictionary of [Integer, Text]; Id: Integer): Boolean
begin
    if Dict.ContainsKey(Id) then
        Message('Key %1 exists in the dictionary', Id)
    else
        Message('Key %1 does not exist in the dictionary', Id);
    exit(Dict.ContainsKey(Id));
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    CheckKeyExists(MyDictionary, 1);
    CheckKeyExists(MyDictionary, 3);
end;

procedure GetDictionaryCount(var Dict: Dictionary of [Integer, Text]): Integer
begin
    exit(Dict.Count());
end;

var
    MyDictionary: Dictionary of [Integer, Text];
    ItemCount: Integer;
begin
    MyDictionary.Add(1, 'Apple');
    MyDictionary.Add(2, 'Banana');
    ItemCount := GetDictionaryCount(MyDictionary);
    Message('Total items in dictionary: %1', ItemCount);
end;

procedure GetValueFromDictionary(var Dict: Dictionary of [Integer, Text]; Id: Integer; var Value: Text): Boolean
begin
    if Dict.Get(Id, Value) then begin
        Message('The value for Key %1 is %2', Id, Value);
        exit(true);
    end else begin
        Message('Key %1 not found in the dictionary', Id);
        exit(false);
    end;
end;

var
    MyDictionary: Dictionary of [Integer, Text];
    Value: Text;
begin
    MyDictionary.Add(1, 'Apple');
    GetValueFromDictionary(MyDictionary, 1, Value);
end;

procedure GetValueDirectFromDictionary(var Dict: Dictionary of [Integer, Text]; Id: Integer): Text
var
    Value: Text;
begin
    Value := Dict.Get(Id);
    Message('The value for Key %1 is %2', Id, Value);
    exit(Value);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    GetValueDirectFromDictionary(MyDictionary, 1);
end;

procedure GetAllKeys(var Dict: Dictionary of [Integer, Text]): List of [Integer]
var
    KeyCollection: List of [Integer];
    Key: Integer;
begin
    KeyCollection := Dict.Keys();
    foreach Key in KeyCollection do
        Message('Key: %1', Key);
    exit(KeyCollection);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    MyDictionary.Add(2, 'Banana');
    GetAllKeys(MyDictionary);
end;

procedure RemoveFromDictionary(var Dict: Dictionary of [Integer, Text]; Id: Integer)
begin
    if Dict.ContainsKey(Id) then begin
        Dict.Remove(Id);
        Message('Key %1 has been removed', Id);
    end else
        Message('Key %1 not found in the dictionary', Id);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    RemoveFromDictionary(MyDictionary, 1);
end;

procedure SetDictionaryValue(var Dict: Dictionary of [Integer, Text]; Id: Integer; Value: Text)
begin
    Dict.Set(Id, Value);
    Message('Key %1 is now associated with %2', Id, Value);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    SetDictionaryValue(MyDictionary, 1, 'Orange');
end;

procedure SetDictionaryValueWithOld(var Dict: Dictionary of [Integer, Text]; Id: Integer; Value: Text): Text
var
    OldValue: Text;
begin
    Dict.Set(Id, Value, OldValue);
    Message('Key %1 was associated with %2, now with %3', Id, OldValue, Value);
    exit(OldValue);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
    OldValue: Text;
begin
    MyDictionary.Add(1, 'Apple');
    OldValue := SetDictionaryValueWithOld(MyDictionary, 1, 'Orange');
end;

procedure GetAllValues(var Dict: Dictionary of [Integer, Text]): List of [Text]
var
    ValueCollection: List of [Text];
    Value: Text;
begin
    ValueCollection := Dict.Values();
    foreach Value in ValueCollection do
        Message('Value: %1', Value);
    exit(ValueCollection);
end;

var
    MyDictionary: Dictionary of [Integer, Text];
begin
    MyDictionary.Add(1, 'Apple');
    MyDictionary.Add(2, 'Banana');
    GetAllValues(MyDictionary);
end;

    procedure SummarizeOutstandingAmountByVendor()
    var
        VendorLedgerEntry: Record "Vendor Ledger Entry";
        VendorOutstandingDict: Dictionary of [Code[20], Decimal];
        VendorNo: Code[20];
        OutstandingAmount: Decimal;
    begin
        VendorLedgerEntry.SetAutoCalcFields(Amount);
        VendorLedgerEntry.SetRange("Open", true); // กำหนดช่วงให้เลือกเฉพาะรายการที่ยังไม่ปิด
        if VendorLedgerEntry.FindSet() then
            repeat
                VendorNo := VendorLedgerEntry."Vendor No.";
                if VendorOutstandingDict.ContainsKey(VendorNo) then begin
                    // อัปเดตยอดค้างชำระหากมีผู้ขายคนเดียวกันใน Dictionary
                    VendorOutstandingDict.Get(VendorNo, OutstandingAmount);
                    OutstandingAmount := OutstandingAmount + VendorLedgerEntry.Amount;
                    VendorOutstandingDict.Set(VendorNo, OutstandingAmount);
                end else begin
                    // เพิ่มผู้ขายใหม่และยอดค้างชำระเข้าไปใน Dictionary
                    VendorOutstandingDict.Add(VendorNo, VendorLedgerEntry.Amount);
                end;
            until VendorLedgerEntry.Next() = 0;

        // อ่านและแสดงผลแต่ละ Vendor No. และ Outstanding Amount
        foreach VendorNo in VendorOutstandingDict.Keys() do begin
            VendorOutstandingDict.Get(VendorNo, OutstandingAmount);
            Message('Vendor No: %1, Outstanding Amount: %2', VendorNo, OutstandingAmount);
        end;
    end;